Amiga ISO Collection/AmigaUtilCD2.iso/WordProcessors/JFF-WW1.DMS/in.adf/Install Wordworth

Text File | 1992-09-02 | 16.2 KB | 824 lines

; $VER: Digita Wordworth Amiga 1200/4000 Special Edition V1 4/108/93
; Copyright (C) Digita International

(complete 0)


; The amount of space needed on the hard disk to install
(set HDSizeNeeded 3)


; Start string definitions
(set #ProgName
(cat "Wordworth"
))

(set #LongProgName
(cat #ProgName " Amiga 1200/4000 Special Edition"
))

(set #Welcome-Pirate
(cat "\nWillkommen zur " #LongProgName " Installation\n\n"
    "Copyright (C) 1993 Digita International\n\n\n\n"
    "Diese Version von Wordworth ist kostenloser Bestandteil des "
    "Desktop Dynamite Pack.\n\n"
    "Nicht für separaten Verkauf."
))

(set #InsertDiskMsg
(cat "\nBenötige die Diskette mit dem Namen\n\n"
))

(set #InsertAmigaDiskMsg
(cat "\nBenötige die Amiga Workbench Diskette mit dem Namen\n\n"
))

(set #diskhelp
(cat "\n    Wenn sich die richtige Diskette im Laufwerk befindet, Sie dennoch nicht weiterkommen, "
    "ist der Name der Diskette falsch.\n"
    "    Stellen Sie sicher, daß der Diskettenname nicht mit 'copy_of_', oder Leerzeichen beginnt oder aufhört.\n\n\n"
))

(set #WwDiskName
(cat "Wordworth"
))

(set #AgfaFontsDiskName
(cat "Agfa-Fonts"
))

(set #WwSpellDiskName
(cat "WwSpell"
))

(set #WwThesDiskName
(cat "WwThes"
))

(set #WwSystemDiskName
(cat "WwSystem"
))

(set #WwSystemMiscFiles
(cat #WwSystemDiskName ":MiscFiles"
))

(set #WwUtilities
(cat #WwDiskName ":Utilities"
))

(set #WwMiscFiles
(cat #WwDiskName ":MiscFiles"
))

(set #InstallIconName
(cat #WwDiskName ":Install Wordworth"
))

(set #BadKick
(cat #LongProgName " benötigt Workbench 3 oder höher."
))

(set #DestChoicePrompt
(cat "\n\n\nWo soll das Programm " #ProgName "installiert werden ?"
))

(set #FloppyChoiceMsg
(cat "Auf Disketten"
))

(set #HardDiskChoiceMsg
(cat "Auf Festplatte"
))

(set #DestChoiceHelp
(cat "\n    Wählen Sie die Schaltfläche \"Auf Festplatte\" um das "
    "Programm " #ProgName " auf Ihrer Festplatte zu installieren.\n\n"
    "    Wählen Sie die Schaltfläche \"Auf Diskette\" um das "
    "Programm " #ProgName " auf Sicherungsdisketten zu installieren.\n\n\n"
))

(set #FloppyBackupsMsg
(cat "\n\nWichtig:  Benutzen Sie für die " #ProgName "Installation "
    " nicht Ihre Originaldisketten. Fertigen Sie Sicherungskopien von " #ProgName
    " an bevor Sie die Installation fortsetzen."
))

(set #FloppyFontDest
(cat #WwDiskName ":Fonts"
))

(set #FloppyDriverDest
(cat #WwDiskName ":Devs/Printers"
))

(set #FloppyDriverSource
(cat #WwDiskName ":Devs/Printers"
))

(set #FloppyWorkingMsg
(cat "Bitte warten... Ihre Disketten werden installiert."
))

(set #FloppySpellLoc
(cat #WwSpellDiskName ":Spell"
))

(set #FloppyThesLoc
(cat #WwThesDiskName ":Spell"
))

(set #FloppyPrefsDest
(cat #WwDiskName ":WordworthPrefs"
))


(set #HardDiskDefaultDest
(cat "Work:"
))

(set #FontSource
(cat #WwDiskName ":Fonts"
))

(set #LibSource
(cat #WwDiskName ":Libs"
))

(set #DocSource
(cat #WwDiskName ":Docs"
))

(set #ClipArtSource
(cat #WwDiskName ":DigitaClipArt"
))

(set #AgfaFontSource
(cat #AgfaFontsDiskName ":Intellifont"
))

(set #SpellSource
(cat #WwSpellDiskName ":Spell"
))

(set #ThesSource
(cat #WwThesDiskName ":Spell"
))

(set #AmigaDriverDiskName
(cat "Storage3.0"
))

(set #AmigaDriverSource
(cat #AmigaDriverDiskName ":printers"
))

(set #AllWwFiles
(cat "Wordworth#?"                 ; Wordworthmenus, messages etc.
))

(set #HelpFileName
(cat "Help"
))

(set #HardDiskFontDest
(cat "SYS:Fonts"
))

(set #HardDiskDriverDest
(cat "SYS:Devs/Printers"
))

(set #HardDiskLibDest
(cat "SYS:Libs"
))

(set #HardDiskDestChoiceMsg
(cat "Wo soll das Programm\n" #ProgName " installiert werden ?"
))

(set #HardDiskDestChoiceHelp
(cat "    Wählen Sie das Verzeichnis in das " #ProgName "installiert "
    "werden soll, und klichen dann Proceed (ein neues Verzeichnis mit dem "
    "Namen \"" #ProgName "\" wird angelegt und enthält " #ProgName ".)"
))

(set #HardDiskDestChoiceConfirmMsg1
(cat "\nSind Sie sicher, daß " #ProgName " in \n\n\""
))

(set #HardDiskDestChoiceConfirmMsg2
(cat "\"\n\n\n\n(Ein neues Verzeichnis mit dem Namen \"" #ProgName "\" wird angelegt und enthält " #ProgName ".)"
))

(set #HardDiskDestChoiceConfirmHelp
(cat "    Klicken Sie YES um das Zielverzeichnis zu bestätigen.\n\n"
    "    Klicken Sie NO um das Zielverzeichnis zu ändern."
))

(set #DrawerExistsMsg
(cat "\nDas Verzeichnis \"Wordworth\" existiert bereits auf Ihrem "
    "Ziellaufwerk.\n\nMöchten Sie das bestehende ersetzen oder ein "
    "neues Ziel wählen?"
))

(set #DrawerExistsChoice1
(cat "Ersetzen"
))

(set #DrawerExistsChoice2
(cat "Neues Ziel wählen"
))

(set #DrawerExistsHelp
(cat "\n    Sie haben ein Zielverzeichnis gewählt in dem sich bereits "
    "eine Version von \"Wordworth\" befindet.\n\n    Klicken Sie \""
    #DrawerExistsChoice1 "\" um diese durch die vorliegende neue Version "
    "von " #ProgName " zu ersetzen.\n    Klicken Sie \"" #DrawerExistsChoice2 "\" "
    "um ein neues Zielverzeichnis zu wählen."
))

(set #NoDiskSpaceMsg
(cat "Auf Ihrer Festplatte befindet sich nicht genügend freie "
    "Speicherkapazität um " #ProgName " zu installieren. Sie benötigen "
    "mindestens " HDSizeNeeded "MB freien Speicher.\n\nBrechen Sie "
    "diese Installation ab und löschen Sie einige Dateien auf Ihrer "
    "Festplatte oder wählen Sie eine andere Partition."
))

(set #HardDiskWorkingMsg
(cat "Bitte warten... Programmwird installiert."
))

(set #HardDiskDocsDrawerName
(cat "Docs"
))

(set #HardDiskClipArtDrawerName
(cat "DigitaClipArt"
))

(set #HardDiskIntelliDrawerName
(cat "Intellifont"
))

(set #HardDiskSpellDrawerName
(cat "Spell"
))

(set #FloppyFinishedMsg
(cat "\nWenn die Installation beendet ist, legen Sie die \""
    #WwDiskName "\" Diskette in das interne Laufwerk und booten Sie "
    "Ihren Amiga."
))

(set #ImportantFinishedMsg
(cat "\nWICHTIG\n\n\nBitte vergessen Sie nicht Ihre Registrierkarte "
    "auszufüllen und an uns zurückzusenden.\n\nNur registrierte Benutzer "
    "erhalten technischen Support, Update-Angebote, Vergünstigungen und "
    "Produktinformationen."
))




;BEGINNING OF INSTALLATION

(if (not (exists "RAM:Temp"))
    (
        (makedir "RAM:Temp" )
    )
)

(makeassign "T" "RAM:Temp")

(askdisk
    (prompt #InsertDiskMsg #WwDiskName)
    (help #diskhelp)
    (dest #WwDiskName )
)


(if (< (/ (getversion) 65536) 39)
      ( abort #badkick )
)


(copyfiles
    (source #WwUtilities )
    (dest "T:" )
    (pattern "Display")
    (nogauge)
    (optional "nofail")
)

(copyfiles
    (source #WwMiscFiles)
    (dest "T:")
    (pattern "stu#?.iff")
    (nogauge)
    (optional "nofail")
)
(if (exists "T:Display")
    (run "T:Display T:stu.iff T:stu2.iff opt t=7")
)


; INSTALLATION
(message #Welcome-Pirate)

(if
    (askchoice
        (prompt #DestChoicePrompt)
        (choices #HardDiskChoiceMsg
                 #FloppyChoiceMsg
        )
        (help #DestChoiceHelp)
        (default 1)
    )

    ;INSTALL ON FLOPPIES
    (
        (complete 10)
        (message #FloppyBackupsMsg)

        (set FontDest #FloppyFontDest)
        (set DriverDest #FloppyDriverDest)

        (askdisk
            (prompt #InsertDiskMsg #WwDiskName)
            (help #diskhelp)
            (dest #WwDiskName)
        )
        (working
            (prompt #FloppyWorkingMsg)
        )
        (complete 30)
        (copyfiles
            (source #WwMiscFiles)
            (dest "T:")
            (pattern "#?info")
            (nogauge)
        )
        (complete 50)
        (copyfiles
            (source "T:")
            (dest (cat #WwDiskName ":"))
            (pattern "#?.info")
            (nogauge)
        )

        (foreach #DocSource "#?"            ; for each of the docs in the drawer
            (
                (tooltype
                    (dest (tackon #DocSource @each-name))
                    (setdefaulttool (cat #WwSystemDiskName ":Ww"))    ; change default tool to right one
                )
            )
        )

        (complete 70)

        (tooltype
            (dest #InstallIconName)            ; make Install icon float out the way
            (noposition)
        )

        (copyfiles
            (source #WwMiscFiles)
            (dest "T:")
            (Pattern "writeprefs")            ; copy the prefs writing prog to ram
            (nogauge)
        )

        ; add AgfaFonts copy to startup-sequence.
        (textfile
            (dest (cat #WwDiskName ":s/User-Startup"))
            (include (tackon #WwMiscFiles "FontStartup"))
        )

        (delete (tackon #WwUtilities "Display"))
        (delete (tackon #WwMiscFiles "stu.iff"))
        (delete (tackon #WwMiscFiles "stu2.iff"))

        (complete 80)
        (set DictLoc #FloppySpellLoc)
        (set ThesLoc #FloppyThesLoc)
        (set PrefsDest #FloppyPrefsDest)

        (set @default-dest "")
    ) ;end InstallFloppy


    ;INSTALL ON HARD DISK
    (
        (complete 10)
        (set MyDefault #HardDiskDefaultDest)
        (set FontDest #HardDiskFontDest)
        (set DriverDest #HardDiskDriverDest)
        (set LibDest #HardDiskLibDest)
        (set OK 0)

        (until (= OK 1)
            (set DestPath
                (askdir
                    (prompt #HardDiskDestChoiceMsg)
                    (help #HardDiskDestChoiceHelp)
                    (default MyDefault)
                )
            )

            (if
                (askbool
                    (prompt #HardDiskDestChoiceConfirmMsg1 DestPath #HardDiskDestChoiceConfirmMsg2)
                    (help #HardDiskDestChoiceConfirmHelp)
                )
                (set OK 1)
            ) ;endif

            (if (= OK 1)
                (if (exists (tackon DestPath "Wordworth")) ; if there is already a drawer named Wordworth
                    (
                        (if
                            (askbool
                                (prompt #DrawerExistsMsg)
                                (choices #DrawerExistsChoice1 #DrawerExistsChoice2)
                                (help #DrawerExistsHelp)
                                (default 0)
                            )
                            ( ; [true] Lets replace it
                                (set OK 1)
                            )
                            ( ;else [false]
                                (set OK 0)
                            )
                        )
                    )
                ) ;endif
            )

            (if (= OK 1)
                (
                    ; Multiply MB by 1024 twice to get number of bytes
                    (set SpaceNeeded (* (* HDSizeNeeded 1024) 1024))
                    (if (< (getdiskspace DestPath) SpaceNeeded)
                        (
                            (message #NoDiskSpaceMsg)
                            (set OK 0)
                        )
                    ) ;endif
                )
            ) ;endif
        ) ;end until


        (set WwDrawerDest (tackon DestPath #ProgName))

        (set #HardDiskSpellLoc
        (cat (tackon WwDrawerDest #HardDiskSpellDrawerName)
        ))

        (set #HardDiskIntelliLoc
        (cat (tackon WwDrawerDest #HardDiskIntelliDrawerName)
        ))

        (set #HardDiskClipArtLoc
        (cat (tackon WwDrawerDest #HardDiskClipArtDrawerName)
        ))

        (set #HardDiskDocsLoc
        (cat (tackon WwDrawerDest #HardDiskDocsDrawerName)
        ))

        (set #HardDiskPrefsDest
        (cat (tackon WwDrawerDest "WordworthPrefs")
        ))

        ; Okay to copy files
        (makedir WwDrawerDest)

        (askdisk
            (prompt #InsertDiskMsg #WwDiskName)
            (help #diskhelp)
            (dest #WwDiskName)
        )

        (working
            (prompt #HardDiskWorkingMsg)
        )
        (copyfiles
            (source #WwMiscFiles)
            (dest "T:")
            (Pattern "writeprefs")            ; copy the prefs writing prog to ram
            (nogauge)
        )

        (copyfiles
            (source #FontSource)
            (dest FontDest)
            (pattern "~(topaz)")        ; everything but topaz
            (fonts)                                    ; copy Ww ...Hi fonts to system
            (optional "force")            ; ignore delete protection
        )

        (copyfiles
            (source #LibSource)
            (dest LibDest)
            (pattern "WW#?")                    ; copy the Ww libraries to system
        )
        (copyfiles
            (source #FloppyDriverSource)
            (dest DriverDest)
            (pattern "Generic")                ; copy the Generic driver to the system
            (optional "force")
        )

        (complete 15)
        (makedir
            (#HardDiskDocsLoc)
            (infos)
        )
        (copyfiles
            (source #DocSource)
            (dest #HardDiskDocsLoc)
            (infos)
            (all)                                ; copy all the Docs
        )
        (foreach #HardDiskDocsLoc "#?"            ; for each of the docs in the drawer
            (
                (tooltype
                    (dest (tackon #HardDiskDocsLoc @each-name))
                    (setdefaulttool "/Ww")    ; change default tool to right one
                )
            )
        )

        (complete 30)
        (makedir
            (#HardDiskClipArtLoc)
            (infos)
        )
        (copyfiles
            (source #ClipArtSource)
            (dest #HardDiskClipArtLoc)
            (infos)
            (all)                                    ; copy all the ClipArt
        )

        (copyfiles
            (source (cat #WwDiskName ":"))
            (dest WwDrawerDest)                ; copy all the Wordworthmenus,
            (pattern #AllWwFiles )            ; messages etc. files
            (optional "force")
        )
        (copyfiles
            (source (cat #WwDiskName ":"))
            (dest WwDrawerDest)                ; copy all the IconFiles
            (pattern "IconFile#?")
            (optional "force")
        )
        (copyfiles
            (source (cat #WwDiskName ":"))
            (dest WwDrawerDest)                ; copy the Help file
            (pattern #HelpFileName)
            (optional "force")
        )

        (askdisk
            (prompt #InsertDiskMsg #AgfaFontsDiskName)
            (help #diskhelp)
            (dest #AgfaFontsDiskName)
        )

        (complete 40)
        (makedir
            (#HardDiskIntelliLoc)
            (infos)
        )
        (copyfiles
            (source #AgfaFontSource)
            (dest #HardDiskIntelliLoc)                ; copy the Intellifont
            (all)                                    ; drawer and contents
        )
        (copyfiles
            (source (cat #AgfaFontsDiskName ":"))
            (dest WwDrawerDest)
            (infos)
            (pattern "AGFAInstall")            ; copy the AGFAInstall program
        )

        (askdisk
            (prompt #InsertDiskMsg #WwSpellDiskName)
            (help #diskhelp)
            (dest #WwSpellDiskName)
        )

        (complete 60)
        (makedir
            (#HardDiskSpellLoc)
            (infos)
        )
        (copyfiles
            (source #SpellSource)
            (dest #HardDiskSpellLoc)
            (infos)
            (all)                                    ; copy spell drawer and stuff
        )

        (askdisk
            (prompt #InsertDiskMsg #WwThesDiskName)
            (help #diskhelp)
            (dest #WwThesDiskName)
        )

        (copyfiles
            (source #ThesSource)
            (dest #HardDiskSpellLoc)
            (pattern "Thesaurus")                                    ; copy thesaurus
        )

        (complete 75)
        (askdisk
            (prompt #InsertDiskMsg #WwSystemDiskName)
            (help #diskhelp)
            (dest #WwSystemDiskName)
        )

        (copyfiles
            (source (cat #WwSystemDiskName ":"))
            (dest WwDrawerDest)
            (Pattern "Ww")                        ; copy the program
            (optional "force")
        )
        (copyfiles
            (source #WwSystemMiscFiles)
            (dest WwDrawerDest)
            (Pattern "Ww.info")                ; copy HD Ww infos
        )
        (copyfiles
            (source #WwSystemMiscFiles)
            (dest WwDrawerDest)
            (Pattern "WordworthPrefs.info")                ; copy HD Prefs infos
        )
        (tooltype
            (dest (tackon WwDrawerDest "WordworthPrefs"))
            (setdefaulttool "Ww")            ; make sure default tool is right
        )

        (copyfiles
            (source #WwSystemMiscFiles)
            (dest DestPath)
            (pattern "Wordworth.info")
        )                                                        ; copy wordworth drawer info
        (tooltype
            (dest (tackon DestPath "Wordworth"))
            (noposition)                            ; make drawer icon 'floating'
        )


        (set DictLoc #HardDiskSpellLoc)
        (set ThesLoc #HardDiskSpellLoc)
        (set PrefsDest #HardDiskPrefsDest)

        (set @default-dest DestPath)

      (complete 80)
    ) ;end InstallHD
) ;endif



; INSTALL PRINTER

; Get Users Printer Choice
(askdisk
    (prompt #InsertDiskMsg #WwSystemDiskName)
    (help #diskhelp)
    (dest #WwSystemDiskName)
)

(set ChosenDriver "Generic")

(run "WwSystem:select WwSystem:WwPrinterList")

(set ChosenDriver (getenv "wwDriver"))
(set TopBord (getenv "wwTop"))
(set BotBord (getenv "wwBottom"))
(set LeftBord (getenv "wwLeft"))
(set RightBord (getenv "wwRight"))


(complete 85)
; copy appropriate driver to destination
; Is it a driver we supply?
; If yes, get driver from Wordworth disk set,
; else get from Workbench Storage disks
; Ignore if a Postscript printer


(if (= FontDest #FloppyFontDest)
    (askdisk
        (prompt #InsertDiskMsg #WwDiskName)
        (help #diskhelp)
        (dest #WwDiskName)
    )
)
(if (NOT (= ChosenDriver "NoDriver"))
    (
        (if (NOT (= ChosenDriver "PostScript"))
            (
                ; Get drivers from Wordworth disks
                (set SourcePath #WwSystemMiscFiles)

                (if (NOT (= ChosenDriver "CanonBJ130"))
                    (if (NOT (= ChosenDriver "CanonEpson"))
                        (
                            ; All other drivers from Workbench disks
                            (set SourcePath #AmigaDriverSource)
                        )
                    )
                )
            ) ;end compound if
        ) ; end if not postscript
    ) ;end compound if
)

; copy driver if not Postscript, not NoDriver and not already exists
(if (NOT (= ChosenDriver "NoDriver"))
    (
        (if (NOT (exists (tackon DriverDest ChosenDriver)))
            (
                (if (= SourcePath #AmigaDriverSource)
                    (askdisk
                        (prompt #InsertAmigaDiskMsg #AmigaDriverDiskName)
                        (help #diskhelp)
                        (dest #AmigaDriverDiskName)
                    )
                )    ; end compound true

                (copyfiles
                    (source SourcePath)
                    (dest "T:")
                    (pattern ChosenDriver)
                    (nogauge)
                ) ; end compound false
            ) ; end if
        ) ; endif
    )    ; end compound true
) ; end if

(complete 90)
; Now copy fonts to T:
(makedir "T:WwFonts")

(if (= FontDest #FloppyFontDest)
    (askdisk
        (prompt #InsertDiskMsg #WwDiskName)
        (help #diskhelp)
        (dest #WwDiskName)
    )
)

(if (exists "ram:script")
    (
        (execute "ram:script")

        ; Now copy fonts in T: to the system fonts drawer
        (copyfiles
            (source "T:WwFonts")
            (dest FontDest)
            (all)
        )
    )
)

(if (exists (tackon "T:" ChosenDriver))
    (copyfiles
        (source "T:")
        (dest DriverDest)
        (pattern ChosenDriver)
    )
)

; Lets write Generic driver if NoDriver given
(if (= ChosenDriver "NoDriver")
    (set ChosenDriver "Generic")
)

; Lets set the WordworthPrefs file
(run
(cat "T:writeprefs \"" PrefsDest "\" \"" DictLoc "\" \"" ThesLoc "\" \"" ChosenDriver "\" \"" TopBord "\" \"" BotBord "\" \"" LeftBord "\" \"" RightBord "\""
))

(if (= FontDest #FloppyFontDest)
    (message #FloppyFinishedMsg)
)

;clean up ram disk
(delete "RAM:script")
(run "delete T:#? all")


(complete 100)
(message #ImportantFinishedMsg)
(exit)